Apertura del repositorio

indra/newview/app_settings/shaders/class1/gltf/pbrmetallicroughnessF.glsl

@@ -0,0 +1,330 @@
+/**
+ * @file pbrmetallicroughnessF.glsl
+ *
+ * $LicenseInfo:firstyear=2024&license=viewerlgpl$
+ * Second Life Viewer Source Code
+ * Copyright (C) 2022, Linden Research, Inc.
+ *
+ * This library is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU Lesser General Public
+ * License as published by the Free Software Foundation;
+ * version 2.1 of the License only.
+ *
+ * This library is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+ * Lesser General Public License for more details.
+ *
+ * You should have received a copy of the GNU Lesser General Public
+ * License along with this library; if not, write to the Free Software
+ * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA
+ *
+ * Linden Research, Inc., 945 Battery Street, San Francisco, CA  94111  USA
+ * $/LicenseInfo$
+ */
+
+/*[EXTRA_CODE_HERE]*/
+
+
+// GLTF pbrMetallicRoughness implementation
+
+uniform int gltf_material_id;
+
+vec3 emissiveColor = vec3(0,0,0);
+float metallicFactor = 1.0;
+float roughnessFactor = 1.0;
+float minimum_alpha = -1.0;
+
+layout (std140) uniform GLTFMaterials
+{
+    // see pbrmetallicroughnessV.glsl for packing
+    vec4 gltf_material_data[MAX_UBO_VEC4S];
+};
+
+void unpackMaterial()
+{
+    if (gltf_material_id > -1)
+    {
+        int idx = gltf_material_id*12;
+        emissiveColor = gltf_material_data[idx+10].rgb;
+        roughnessFactor = gltf_material_data[idx+11].g;
+        metallicFactor = gltf_material_data[idx+11].b;
+        minimum_alpha -= gltf_material_data[idx+11].a;
+    }
+}
+
+// ==================================
+// needed by all variants
+// ==================================
+uniform sampler2D diffuseMap;  //always in sRGB space
+uniform sampler2D emissiveMap;
+in vec3 vary_position;
+in vec4 vertex_color;
+in vec2 base_color_uv;
+in vec2 emissive_uv;
+
+void mirrorClip(vec3 pos);
+vec4 encodeNormal(vec3 n, float env, float gbuffer_flag);
+
+vec3 linear_to_srgb(vec3 c);
+vec3 srgb_to_linear(vec3 c);
+// ==================================
+
+
+// ==================================
+// needed by all lit variants
+// ==================================
+#ifndef UNLIT
+uniform sampler2D normalMap;
+uniform sampler2D metallicRoughnessMap;
+uniform sampler2D occlusionMap;
+in vec3 vary_normal;
+in vec3 vary_tangent;
+flat in float vary_sign;
+in vec2 normal_uv;
+in vec2 metallic_roughness_uv;
+in vec2 occlusion_uv;
+#endif
+// ==================================
+
+
+// ==================================
+// needed by all alpha variants
+// ==================================
+#ifdef ALPHA_BLEND
+in vec3 vary_fragcoord;
+uniform vec4 clipPlane;
+uniform float clipSign;
+void waterClip(vec3 pos);
+void calcAtmosphericVarsLinear(vec3 inPositionEye, vec3 norm, vec3 light_dir, out vec3 sunlit, out vec3 amblit, out vec3 atten, out vec3 additive);
+vec4 applySkyAndWaterFog(vec3 pos, vec3 additive, vec3 atten, vec4 color);
+#endif
+// ==================================
+
+
+// ==================================
+// needed by lit alpha
+// ==================================
+#if defined(ALPHA_BLEND) && !defined(UNLIT)
+
+#ifdef HAS_SUN_SHADOW
+uniform sampler2D lightMap;
+uniform vec2 screen_res;
+#endif
+
+// Lights
+// See: LLRender::syncLightState()
+uniform vec4 light_position[8];
+uniform vec3 light_direction[8]; // spot direction
+uniform vec4 light_attenuation[8]; // linear, quadratic, is omni, unused, See: LLPipeline::setupHWLights() and syncLightState()
+uniform vec3 light_diffuse[8];
+uniform vec2 light_deferred_attenuation[8]; // light size and falloff
+
+uniform int sun_up_factor;
+uniform vec3 sun_dir;
+uniform vec3 moon_dir;
+
+void calcHalfVectors(vec3 lv, vec3 n, vec3 v, out vec3 h, out vec3 l, out float nh, out float nl, out float nv, out float vh, out float lightDist);
+float calcLegacyDistanceAttenuation(float distance, float falloff);
+float sampleDirectionalShadow(vec3 pos, vec3 norm, vec2 pos_screen);
+void sampleReflectionProbes(inout vec3 ambenv, inout vec3 glossenv,
+        vec2 tc, vec3 pos, vec3 norm, float glossiness, bool transparent, vec3 amblit_linear);
+
+void calcDiffuseSpecular(vec3 baseColor, float metallic, inout vec3 diffuseColor, inout vec3 specularColor);
+
+vec3 pbrBaseLight(vec3 diffuseColor,
+                  vec3 specularColor,
+                  float metallic,
+                  vec3 pos,
+                  vec3 norm,
+                  float perceptualRoughness,
+                  vec3 light_dir,
+                  vec3 sunlit,
+                  float scol,
+                  vec3 radiance,
+                  vec3 irradiance,
+                  vec3 colorEmissive,
+                  float ao,
+                  vec3 additive,
+                  vec3 atten);
+
+vec3 pbrCalcPointLightOrSpotLight(vec3 diffuseColor, vec3 specularColor,
+                    float perceptualRoughness,
+                    float metallic,
+                    vec3 n, // normal
+                    vec3 p, // pixel position
+                    vec3 v, // view vector (negative normalized pixel position)
+                    vec3 lp, // light position
+                    vec3 ld, // light direction (for spotlights)
+                    vec3 lightColor,
+                    float lightSize, float falloff, float is_pointlight, float ambiance);
+
+#endif
+// ==================================
+
+
+// ==================================
+// output definition
+// ==================================
+#if defined(ALPHA_BLEND) || defined(UNLIT)
+out vec4 frag_color;
+#else
+out vec4 frag_data[4];
+#endif
+// ==================================
+
+
+void main()
+{
+    unpackMaterial();
+// ==================================
+// all variants
+//   mirror clip
+//   base color
+//   masking
+//   emissive
+// ==================================
+    vec3 pos = vary_position;
+    mirrorClip(pos);
+
+#ifdef ALPHA_BLEND
+    //waterClip(pos);
+#endif
+
+    vec4 basecolor = texture(diffuseMap, base_color_uv.xy).rgba;
+    basecolor.rgb = srgb_to_linear(basecolor.rgb);
+    basecolor *= vertex_color;
+
+    if (basecolor.a < minimum_alpha)
+    {
+        discard;
+    }
+
+    vec3 emissive = emissiveColor;
+    emissive *= srgb_to_linear(texture(emissiveMap, emissive_uv.xy).rgb);
+// ==================================
+
+// ==================================
+// all lit variants
+//   prepare norm
+//   prepare orm
+// ==================================
+#ifndef UNLIT
+    // from mikktspace.com
+    vec3 vNt = texture(normalMap, normal_uv.xy).xyz*2.0-1.0;
+    float sign = vary_sign;
+    vec3 vN = vary_normal;
+    vec3 vT = vary_tangent.xyz;
+
+    vec3 vB = sign * cross(vN, vT);
+    vec3 norm = normalize( vNt.x * vT + vNt.y * vB + vNt.z * vN );
+    norm *= gl_FrontFacing ? 1.0 : -1.0;
+
+    // RGB = Occlusion, Roughness, Metal
+    // default values, see LLViewerTexture::sDefaultPBRORMImagep
+    //   occlusion 1.0
+    //   roughness 0.0
+    //   metal     0.0
+    vec3 orm = texture(metallicRoughnessMap, metallic_roughness_uv.xy).rgb;
+    orm.r = texture(occlusionMap, occlusion_uv.xy).r;
+    orm.g *= roughnessFactor;
+    orm.b *= metallicFactor;
+#endif
+// ==================================
+
+// ==================================
+// non alpha output
+// ==================================
+#ifndef ALPHA_BLEND
+#ifdef UNLIT
+    vec4 color = basecolor;
+    color.rgb += emissive.rgb;
+    frag_color = color;
+#else
+    frag_data[0] = max(vec4(basecolor.rgb, 0.0), vec4(0));
+    frag_data[1] = max(vec4(orm.rgb,0.0), vec4(0));
+    frag_data[2] = encodeNormal(norm, 0, GBUFFER_FLAG_HAS_PBR);
+
+//#if defined(HAS_EMISSIVE)
+    frag_data[3] = max(vec4(emissive,0), vec4(0));
+//#endif
+#endif
+#endif
+
+
+// ==================================
+// alpha implementation
+// ==================================
+#ifdef ALPHA_BLEND
+
+    float scol = 1.0;
+    vec3 sunlit;
+    vec3 amblit;
+    vec3 additive;
+    vec3 atten;
+
+    vec3  light_dir;
+
+#ifdef UNLIT
+    light_dir = vec3(0,0,1);
+    vec3 norm = vec3(0,0,1);
+#else
+    light_dir = (sun_up_factor == 1) ? sun_dir : moon_dir;
+#endif
+
+    calcAtmosphericVarsLinear(pos.xyz, norm, light_dir, sunlit, amblit, additive, atten);
+
+#ifndef UNLIT
+    vec3 sunlit_linear = srgb_to_linear(sunlit);
+
+    vec2 frag = vary_fragcoord.xy/vary_fragcoord.z*0.5+0.5;
+
+#ifdef HAS_SUN_SHADOW
+    scol = sampleDirectionalShadow(pos.xyz, norm.xyz, frag);
+#endif
+
+    float perceptualRoughness = orm.g * roughnessFactor;
+    float metallic = orm.b * metallicFactor;
+
+    // PBR IBL
+    float gloss      = 1.0 - perceptualRoughness;
+    vec3  irradiance = vec3(0);
+    vec3  radiance  = vec3(0);
+    sampleReflectionProbes(irradiance, radiance, vary_position.xy*0.5+0.5, pos.xyz, norm.xyz, gloss, true, amblit);
+
+    vec3 diffuseColor;
+    vec3 specularColor;
+    calcDiffuseSpecular(basecolor.rgb, metallic, diffuseColor, specularColor);
+
+    vec3 v = -normalize(pos.xyz);
+
+    vec3 color = pbrBaseLight(diffuseColor, specularColor, metallic, v, norm.xyz, perceptualRoughness, light_dir, sunlit_linear, scol, radiance, irradiance, emissive, orm.r, additive, atten);
+
+    vec3 light = vec3(0);
+
+    // Punctual lights
+#define LIGHT_LOOP(i) light += pbrCalcPointLightOrSpotLight(diffuseColor, specularColor, perceptualRoughness, metallic, norm.xyz, pos.xyz, v, light_position[i].xyz, light_direction[i].xyz, light_diffuse[i].rgb, light_deferred_attenuation[i].x, light_deferred_attenuation[i].y, light_attenuation[i].z, light_attenuation[i].w);
+
+    LIGHT_LOOP(1)
+    LIGHT_LOOP(2)
+    LIGHT_LOOP(3)
+    LIGHT_LOOP(4)
+    LIGHT_LOOP(5)
+    LIGHT_LOOP(6)
+    LIGHT_LOOP(7)
+
+    color.rgb += light.rgb;
+
+    color.rgb = applySkyAndWaterFog(pos.xyz, additive, atten, vec4(color, 1.0)).rgb;
+
+    float a = basecolor.a*vertex_color.a;
+
+    frag_color = max(vec4(color.rgb,a), vec4(0));
+#else // UNLIT
+    vec4 color = basecolor;
+    color.rgb += emissive.rgb;
+    frag_color = color;
+#endif
+#endif  // ALPHA_BLEND
+}
+

indra/newview/app_settings/shaders/class1/gltf/pbrmetallicroughnessV.glsl

@@ -0,0 +1,329 @@
+/**
+ * @file pbrmetallicroughnessV.glsl
+ *
+ * $LicenseInfo:firstyear=2024&license=viewerlgpl$
+ * Second Life Viewer Source Code
+ * Copyright (C) 2022, Linden Research, Inc.
+ *
+ * This library is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU Lesser General Public
+ * License as published by the Free Software Foundation;
+ * version 2.1 of the License only.
+ *
+ * This library is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+ * Lesser General Public License for more details.
+ *
+ * You should have received a copy of the GNU Lesser General Public
+ * License along with this library; if not, write to the Free Software
+ * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA
+ *
+ * Linden Research, Inc., 945 Battery Street, San Francisco, CA  94111  USA
+ * $/LicenseInfo$
+ */
+
+// GLTF pbrMetallicRoughness implementation
+
+uniform mat4 modelview_matrix;
+uniform mat4 projection_matrix;
+
+#ifdef MULTI_UV
+in vec2 texcoord1;
+int base_color_texcoord = 0;
+int emissive_texcoord = 0;
+#ifndef UNLIT
+int normal_texcoord = 0;
+int metallic_roughness_texcoord = 0;
+int occlusion_texcoord = 0;
+#endif
+#endif
+
+uniform int gltf_material_id;
+
+layout (std140) uniform GLTFMaterials
+{
+    // index by gltf_material_id*12
+
+    // [gltf_material_id + [0-1]] -  base color transform
+    // [gltf_material_id + [2-3]] -  normal transform
+    // [gltf_material_id + [4-5]] -  metallic roughness transform
+    // [gltf_material_id + [6-7]] -  emissive transform
+    // [gltf_material_id + [8-9]] -  occlusion transform
+    // [gltf_material_id + 10]    -  emissive factor
+    // [gltf_material_id + 11]    -  .r unused, .g roughness, .b metalness, .a minimum alpha
+
+    // Transforms are packed as follows
+    // packed[0] = vec4(scale.x, scale.y, rotation, offset.x)
+    // packed[1] = vec4(mScale.y, texcoord, 0, 0)
+    vec4 gltf_material_data[MAX_UBO_VEC4S];
+};
+
+vec4[2] texture_base_color_transform;
+vec4[2] texture_normal_transform;
+vec4[2] texture_metallic_roughness_transform;
+vec4[2] texture_emissive_transform;
+vec4[2] texture_occlusion_transform;
+
+void unpackTextureTransforms()
+{
+    if (gltf_material_id != -1)
+    {
+        int idx = gltf_material_id*12;
+
+        texture_base_color_transform[0] = gltf_material_data[idx+0];
+        texture_base_color_transform[1] = gltf_material_data[idx+1];
+
+        texture_normal_transform[0] = gltf_material_data[idx+2];
+        texture_normal_transform[1] = gltf_material_data[idx+3];
+
+        texture_metallic_roughness_transform[0] = gltf_material_data[idx+4];
+        texture_metallic_roughness_transform[1] = gltf_material_data[idx+5];
+
+        texture_emissive_transform[0] = gltf_material_data[idx+6];
+        texture_emissive_transform[1] = gltf_material_data[idx+7];
+
+        texture_occlusion_transform[0] = gltf_material_data[idx+8];
+        texture_occlusion_transform[1] = gltf_material_data[idx+9];
+
+#ifdef MULTI_UV
+        base_color_texcoord = int(gltf_material_data[idx+1].g);
+        emissive_texcoord = int(gltf_material_data[idx+7].g);
+#ifndef UNLIT
+        normal_texcoord = int(gltf_material_data[idx+3].g);
+        metallic_roughness_texcoord = int(gltf_material_data[idx+5].g);
+        occlusion_texcoord = int(gltf_material_data[idx+9].g);
+#endif
+#endif
+    }
+    else
+    {
+        texture_base_color_transform[0] = vec4(1.0, 1.0, 0.0, 0.0);
+        texture_base_color_transform[1] = vec4(0.0, 0.0, 0.0, 0.0);
+
+        texture_normal_transform[0] = vec4(1.0, 1.0, 0.0, 0.0);
+        texture_normal_transform[1] = vec4(0.0, 0.0, 0.0, 0.0);
+
+        texture_metallic_roughness_transform[0] = vec4(1.0, 1.0, 0.0, 0.0);
+        texture_metallic_roughness_transform[1] = vec4(0.0, 0.0, 0.0, 0.0);
+
+        texture_emissive_transform[0] = vec4(1.0, 1.0, 0.0, 0.0);
+        texture_emissive_transform[1] = vec4(0.0, 0.0, 0.0, 0.0);
+
+        texture_occlusion_transform[0] = vec4(1.0, 1.0, 0.0, 0.0);
+        texture_occlusion_transform[1] = vec4(0.0, 0.0, 0.0, 0.0);
+    }
+}
+
+
+in vec3 position;
+in vec4 diffuse_color;
+in vec2 texcoord0;
+out vec2 base_color_uv;
+out vec2 emissive_uv;
+out vec4 vertex_color;
+out vec3 vary_position;
+
+#ifndef UNLIT
+in vec3 normal;
+in vec4 tangent;
+out vec2 normal_uv;
+out vec2 metallic_roughness_uv;
+out vec2 occlusion_uv;
+out vec3 vary_tangent;
+flat out float vary_sign;
+out vec3 vary_normal;
+#endif
+
+vec2 gltf_texture_transform(vec2 texcoord, vec4[2] p)
+{
+    texcoord.y = 1.0 - texcoord.y;
+
+    vec2 Scale = p[0].xy;
+    float Rotation = -p[0].z;
+    vec2 Offset = vec2(p[0].w, p[1].x);
+
+    mat3 translation = mat3(1,0,0, 0,1,0, Offset.x, Offset.y, 1);
+    mat3 rotation = mat3(
+        cos(Rotation), sin(Rotation), 0,
+        -sin(Rotation), cos(Rotation), 0,
+        0, 0, 1);
+
+    mat3 scale = mat3(Scale.x,0,0, 0,Scale.y,0, 0,0,1);
+
+    mat3 matrix = translation * rotation * scale;
+
+    vec2 uvTransformed = ( matrix * vec3(texcoord.xy, 1) ).xy;
+
+    uvTransformed.y = 1.0 - uvTransformed.y;
+
+    return uvTransformed;
+}
+
+#ifndef UNLIT
+vec3 gltf_tangent_space_transform(vec4 vertex_tangent, vec3 vertex_normal, vec4[2] khr_gltf_transform)
+{ //derived from tangent_space_transform in textureUtilV.glsl
+    vec2 weights = vec2(0, 1);
+
+    // Convert to left-handed coordinate system
+    weights.y = -weights.y;
+
+    // Apply KHR_texture_transform (rotation only)
+    float khr_rotation = khr_gltf_transform[0].z;
+    mat2 khr_rotation_mat = mat2(
+        cos(khr_rotation),-sin(khr_rotation),
+        sin(khr_rotation), cos(khr_rotation)
+    );
+    weights = khr_rotation_mat * weights;
+
+    // Convert back to right-handed coordinate system
+    weights.y = -weights.y;
+
+    // Similar to the MikkTSpace-compatible method of extracting the binormal
+    // from the normal and tangent, as seen in the fragment shader
+    vec3 vertex_binormal = vertex_tangent.w * cross(vertex_normal, vertex_tangent.xyz);
+
+    return (weights.x * vertex_binormal.xyz) + (weights.y * vertex_tangent.xyz);
+
+    return vertex_tangent.xyz;
+}
+#endif
+
+#ifdef ALPHA_BLEND
+out vec3 vary_fragcoord;
+#endif
+
+#ifdef HAS_SKIN
+
+layout (std140) uniform GLTFJoints
+{
+    vec4 gltf_joints[MAX_NODES_PER_GLTF_OBJECT];
+};
+
+
+in uvec4 joint;
+in vec4 weight4;
+
+mat4 getGLTFTransform()
+{
+    int i;
+
+    vec4 w = weight4;
+
+    uint i1 = joint.x*3u;
+    uint i2 = joint.y*3u;
+    uint i3 = joint.z*3u;
+    uint i4 = joint.w*3u;
+
+    // lerp the joints
+    vec4 v0 = gltf_joints[i1+0u] * w.x + gltf_joints[i2+0u] * w.y + gltf_joints[i3+0u] * w.z + gltf_joints[i4+0u] * w.w;
+    vec4 v1 = gltf_joints[i1+1u] * w.x + gltf_joints[i2+1u] * w.y + gltf_joints[i3+1u] * w.z + gltf_joints[i4+1u] * w.w;
+    vec4 v2 = gltf_joints[i1+2u] * w.x + gltf_joints[i2+2u] * w.y + gltf_joints[i3+2u] * w.z + gltf_joints[i4+2u] * w.w;
+
+    //unpack into return matrix
+    mat4 ret;
+    ret[0] = vec4(v0.xyz, 0);
+    ret[1] = vec4(v1.xyz, 0);
+    ret[2] = vec4(v2.xyz, 0);
+    ret[3] = vec4(v0.w, v1.w, v2.w, 1.0);
+
+    return ret;
+}
+
+#else
+
+layout (std140) uniform GLTFNodes
+{
+    vec4 gltf_nodes[MAX_NODES_PER_GLTF_OBJECT];
+};
+
+uniform int gltf_node_id = 0;
+
+mat4 getGLTFTransform()
+{
+    mat4 ret;
+    int idx = gltf_node_id*3;
+
+    vec4 src0 = gltf_nodes[idx+0];
+    vec4 src1 = gltf_nodes[idx+1];
+    vec4 src2 = gltf_nodes[idx+2];
+
+    ret[0] = vec4(src0.xyz, 0);
+    ret[1] = vec4(src1.xyz, 0);
+    ret[2] = vec4(src2.xyz, 0);
+
+    ret[3] = vec4(src0.w, src1.w, src2.w, 1);
+
+    return ret;
+}
+
+#endif
+
+void main()
+{
+    unpackTextureTransforms();
+    mat4 mat = getGLTFTransform();
+
+    mat = modelview_matrix * mat;
+
+    vec3 pos = (mat*vec4(position.xyz,1.0)).xyz;
+    vary_position = pos;
+
+    vec4 vert = projection_matrix * vec4(pos, 1.0);
+    gl_Position = vert;
+
+    vec2 bcuv;
+    vec2 emuv;
+
+#ifdef MULTI_UV
+    vec2 uv[2];
+    uv[0] = texcoord0;
+    uv[1] = texcoord1;
+
+    bcuv = uv[base_color_texcoord];
+    emuv = uv[emissive_texcoord];
+#else
+    bcuv = texcoord0;
+    emuv = texcoord0;
+#endif
+
+    base_color_uv = gltf_texture_transform(bcuv, texture_base_color_transform);
+    emissive_uv = gltf_texture_transform(emuv, texture_emissive_transform);
+
+#ifndef UNLIT
+    vec2 normuv;
+    vec2 rmuv;
+    vec2 ouv;
+#ifdef MULTI_UV
+    normuv = uv[normal_texcoord];
+    rmuv = uv[metallic_roughness_texcoord];
+    ouv = uv[occlusion_texcoord];
+#else
+    normuv = texcoord0;
+    rmuv = texcoord0;
+    ouv = texcoord0;
+#endif
+    normal_uv = gltf_texture_transform(normuv, texture_normal_transform);
+    metallic_roughness_uv = gltf_texture_transform(rmuv, texture_metallic_roughness_transform);
+    occlusion_uv = gltf_texture_transform(ouv, texture_occlusion_transform);
+#endif
+
+#ifndef UNLIT
+    vec3 n = (mat*vec4(normal.xyz+position.xyz,1.0)).xyz-pos.xyz;
+    vec3 t = (mat*vec4(tangent.xyz+position.xyz,1.0)).xyz-pos.xyz;
+
+    n = normalize(n);
+    vary_tangent = normalize(gltf_tangent_space_transform(vec4(t, tangent.w), n, texture_normal_transform));
+    vary_sign = tangent.w;
+    vary_normal = n;
+#endif
+
+    vertex_color = diffuse_color;
+#ifdef ALPHA_BLEND
+    vary_fragcoord = vert.xyz;
+#endif
+}
+
+
+
+